fabapp/flake.nix

{
  description = "FabApp";

  inputs = {
    # take unstable if not specified
    # nixpkgs.url = "github:nixos/nixpkgs/release-23.05";
    flake-parts.url = "github:hercules-ci/flake-parts";
  };

  outputs = inputs@{ flake-parts, nixpkgs, ... }:
    flake-parts.lib.mkFlake { inherit inputs; } {
      flake = {
        # Put your original flake attributes here.
      };

      systems = [ "x86_64-linux" ];

      # https://flake.parts/module-arguments.html#persystem-module-parameters
      perSystem = { pkgs, system, ... }: {
        _module.args.pkgs = import nixpkgs {
          inherit system;
          config.allowUnfree = true;
        };

        devShells.default = with pkgs;
          let
            vscodeCustom = pkgs.vscode-with-extensions.override {
              vscodeExtensions = with pkgs.vscode-extensions; [
                # Flutter
                dart-code.dart-code
                dart-code.flutter

                # Nix
                bbenoist.nix
                brettm12345.nixfmt-vscode
              ];
            };
          in mkShell {
            buildInputs = [
              sqlite

              # Dev tools
              just
              vscodeCustom

              # Flutter
              flutter

              # Linux toolchain
              clang_15
              cmake
              ninja
              pkg-config
              gtk3
              pcre
              libepoxy

              # Zig / webAssembly impl.
              zig
              zls
            ];

            # see: https://discourse.nixos.org/t/flutter-run-d-linux-build-process-failed/16552/2
            shellHook = ''
              export LD_LIBRARY_PATH=${libepoxy}/lib
            '';
          };
      };
    };
}